/**
  ** Click each box to trigger the beat.
  */

import ddf.minim.*;
import ddf.minim.analysis.*;

int play;
int numSongs = 5;
Minim minim;
AudioPlayer[] song = new AudioPlayer[numSongs];
BeatDetect[] beat = new BeatDetect[numSongs];
BeatListener[] bl = new BeatListener[numSongs];

String[] songNames = {
  "hiphop05.mp3",
  "exotic05.mp3",
  "deephouse06.mp3",
  "effected04.mp3",
  "ambient01.mp3"};

color[] beatColors = {#ec008c, #f26522, #00aeef, #95e12f, #f6ff0b};

void setup()
{
  size(800, 600);
  background(0);
  frameRate(30);
  noStroke();
  smooth();
  minim = new Minim(this);
  play = 50;
  textFont(createFont("Helvetica", 12));
  textAlign(CENTER);
  ellipseMode(CENTER);


  for (int i=0; i<numSongs; i++) {  
  fill(beatColors[i]);
  rect(50+i*150,400,50,50);
  text("Beat "+(i+1),75+i*150,470);
  song[i] = minim.loadFile(songNames[i], 2048);
  // a beat detection object that is FREQ_ENERGY mode that 
  // expects buffers the length of song's buffer size
  // and samples captured at songs's sample rate
  beat[i] = new BeatDetect(song[i].bufferSize(), song[i].sampleRate());
  // set the sensitivity to 300 milliseconds
  // After a beat has been detected, the algorithm will wait for 300 milliseconds 
  // before allowing another beat to be reported. You can use this to dampen the 
  // algorithm if it is giving too many false-positives. The default value is 10. 
  beat[i].setSensitivity(300);  
  // Make a new beat listener, so that we won't miss any buffers for the analysis.
  bl[i] = new BeatListener(beat[i], song[i]);
  }
}

void draw()
{
  fill(0,8);
  rect(-1,46,width+2,308);
  rect(0,400,width,45);
  for (int i=0; i<numSongs; i++) {
  fill(beatColors[i],5);
  rect(50+i*150,400,50,50);
  }
  stroke(255,30);
  line(play,45,play,355);
  noStroke();
  for (int i=0; i<numSongs; i++) {  
  fill(i*50,i*50,0);
  if ( beat[i].isKick() ) BeatFly(play, 120, 60, i);
  if ( beat[i].isSnare() ) BeatFly(play, 230, 40, i);
  if ( beat[i].isHat() ) BeatFly(play, 300, 20, i);
  }
  play += 12;
  if (play > width-50) {
    play = 50;
  }
}

void mousePressed() {
  for (int i=0; i<numSongs; i++) {
  if (mouseX >50+i*150 && mouseX < 100+i*150 && mouseY > 400 && mouseY < 450) {
    fill(beatColors[i]);
    rect(50+i*150,400,50,50);
    song[i].rewind();
    song[i].play();
    }
  }
}


void stop()
{
  // always close Minim audio classes when you are finished with them
  for (int i=0; i<numSongs; i++) {  
  song[i].close();
  }
  // always stop Minim before exiting
  minim.stop();
  // this closes the sketch
  super.stop();
}